How to make always visible shader

Mehran

Hi,
I am working on a side scroller game that has spine-based characters and 3d enviros.
What we want is for the characters to be always visible, i.e when they go behind objects we need to be able to draw a silhouette of them.
We were able to pull this off by simply adding a pass to my shader with a flat color.
However, this "always visible" pass adds a silhouette of the same color to my characters. Is there any way to fix this?

here is the shader code

// - Vertex Lit + ShadowCaster
// - Premultiplied Alpha Blending (Optional straight alpha input)
// - Double-sided, no depth

Shader "Spine/Spine-Skeleton-Lit AlwaysVisible" {
   Properties {
      _Cutoff ("Shadow alpha cutoff", Range(0,1)) = 0.1
      [NoScaleOffset] _MainTex ("Main Texture", 2D) = "black" {}
      _Color ("always visible color", Color) = (0,0,0,0)
      [Toggle(_STRAIGHT_ALPHA_INPUT)] _StraightAlphaInput("Straight Alpha Texture", Int) = 0
      [Toggle(_DOUBLE_SIDED_LIGHTING)] _DoubleSidedLighting("Double-Sided Lighting", Int) = 0
      [HideInInspector] _StencilRef("Stencil Reference", Float) = 1.0
      [HideInInspector][Enum(UnityEngine.Rendering.CompareFunction)] _StencilComp("Stencil Comparison", Float) = 8 // Set to Always as default

  // Outline properties are drawn via custom editor.
  [HideInInspector] _OutlineWidth("Outline Width", Range(0,8)) = 3.0
  [HideInInspector] _OutlineColor("Outline Color", Color) = (1,1,0,1)
  [HideInInspector] _OutlineReferenceTexWidth("Reference Texture Width", Int) = 1024
  [HideInInspector] _ThresholdEnd("Outline Threshold", Range(0,1)) = 0.25
  [HideInInspector] _OutlineSmoothness("Outline Smoothness", Range(0,1)) = 1.0
  [HideInInspector][MaterialToggle(_USE8NEIGHBOURHOOD_ON)] _Use8Neighbourhood("Sample 8 Neighbours", Float) = 1
  [HideInInspector] _OutlineMipLevel("Outline Mip Level", Range(0,3)) = 0
   }

   SubShader {
      Tags { "Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent" }
      LOD 100

  Stencil {
     Ref[_StencilRef]
     Comp[_StencilComp]
     Pass Keep
  }
     Pass {
     Name "overlay"

     Tags { "Queue" = "Transparent"}

     ZWrite Off
     Ztest Always
     Cull Off
     Blend One OneMinusSrcAlpha

     CGPROGRAM
     #pragma shader_feature _ _STRAIGHT_ALPHA_INPUT         
     #pragma vertex vert
     #pragma fragment frag
     #pragma target 2.0
     #include "UnityCG.cginc"

     struct appdata
     {
     float4 vertex : POSITION;
     };
  
     struct v2f
     {
     float4 vertex : SV_POSITION;
     };
     
     float4 _Color;

     v2f vert(appdata v)
     {
        v2f o;
        o.vertex = UnityObjectToClipPos(v.vertex);
        return o;
     }
     
     fixed4 frag(v2f i) : SV_Target
     {
     return _Color;
     }

     //#include "CGIncludes/Spine-Skeleton-Lit-Common.cginc"
     ENDCG
        }

  Pass {
     Name "Normal"

     Tags { "LightMode"="Vertex" "Queue"="Transparent" "IgnoreProjector"="true" "RenderType"="Transparent" }

     ZWrite Off
     Cull Off
     Blend One OneMinusSrcAlpha

     CGPROGRAM
     #pragma shader_feature _ _STRAIGHT_ALPHA_INPUT
     #pragma shader_feature _ _DOUBLE_SIDED_LIGHTING
     #pragma vertex vert
     #pragma fragment frag
     #pragma target 2.0

     #pragma multi_compile __ POINT SPOT
     #include "CGIncludes/Spine-Skeleton-Lit-Common.cginc"
     ENDCG

   }

  Pass {
     Name "Caster"
     Tags { "LightMode"="ShadowCaster" }
     Offset 1, 1

     Fog { Mode Off }
     ZWrite On
     ZTest LEqual
     Cull Off
     Lighting Off

     CGPROGRAM
     #pragma vertex vertShadow
     #pragma fragment fragShadow
     #pragma multi_compile_shadowcaster
     #pragma fragmentoption ARB_precision_hint_fastest

     #define SHADOW_CUTOFF _Cutoff
     #include "CGIncludes/Spine-Skeleton-Lit-Common-Shadow.cginc"

     ENDCG
  }

   }
   CustomEditor "SpineShaderWithOutlineGUI"
}

Can you guys help? We are using unity's default rendering pipeline
thanks.

Mehran

Harald

The problem is with the fragment shader always returning the same opaque color, even if the texture at this texel would be transparent:

Mehran đã viết
fixed4 frag(v2f i) : SV_Target
{
return _Color;
}

So basically you need something like the following code instead. You can also change blending to normal SrcAlpha OneMinusSrcAlpha blend mode, otherwise you need to premultiply the alpha value to the RGB color value.

// Blend One OneMinusSrcAlpha // change this line 
Blend SrcAlpha OneMinusSrcAlpha // to this line 
...
fixed4 frag(v2f i) : SV_Target
{
    float4 texColor = tex2D(_MainTex, i.uv);
    return fixed4(_Color.rgb, texColor.a);
}

Mehran

thank you Harald,
Here is the code that I made using your input

// - Vertex Lit + ShadowCaster
// - Premultiplied Alpha Blending (Optional straight alpha input)
// - Double-sided, no depth

Shader "Spine/Spine-Skeleton-Lit GHOST 2" {
   Properties{
      _Cutoff("Shadow alpha cutoff", Range(0,1)) = 0.1
      [NoScaleOffset] _MainTex("Main Texture", 2D) = "black" {}
      _Color("always visible color", Color) = (0,0,0,0)
      [Toggle(_STRAIGHT_ALPHA_INPUT)] _StraightAlphaInput("Straight Alpha Texture", Int) = 0
      [Toggle(_DOUBLE_SIDED_LIGHTING)] _DoubleSidedLighting("Double-Sided Lighting", Int) = 0
      [HideInInspector] _StencilRef("Stencil Reference", Float) = 1.0
      [HideInInspector][Enum(UnityEngine.Rendering.CompareFunction)] _StencilComp("Stencil Comparison", Float) = 8 // Set to Always as default

  // Outline properties are drawn via custom editor.
  [HideInInspector] _OutlineWidth("Outline Width", Range(0,8)) = 3.0
  [HideInInspector] _OutlineColor("Outline Color", Color) = (1,1,0,1)
  [HideInInspector] _OutlineReferenceTexWidth("Reference Texture Width", Int) = 1024
  [HideInInspector] _ThresholdEnd("Outline Threshold", Range(0,1)) = 0.25
  [HideInInspector] _OutlineSmoothness("Outline Smoothness", Range(0,1)) = 1.0
  [HideInInspector][MaterialToggle(_USE8NEIGHBOURHOOD_ON)] _Use8Neighbourhood("Sample 8 Neighbours", Float) = 1
  [HideInInspector] _OutlineMipLevel("Outline Mip Level", Range(0,3)) = 0
   }

  SubShader{
     Tags { "Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" }
     LOD 100

     Stencil {
        Ref[_StencilRef]
        Comp[_StencilComp]
        Pass Keep
     }
        Pass {
        Name "overlay"

        Tags { "Queue" = "Transparent"}

        ZWrite Off
        Ztest Always
        Cull Off
        Blend SrcAlpha OneMinusSrcAlpha

        CGPROGRAM
        #pragma shader_feature _ _STRAIGHT_ALPHA_INPUT         
        #pragma vertex vert
        #pragma fragment frag
        #pragma target 2.0
        #include "UnityCG.cginc"


        struct appdata
        {
        float4 vertex : POSITION;
        float2 uv : TEXCOORD0;
        };

        struct v2f
        {
        float2 uv : TEXCOORD0;
        float4 vertex : SV_POSITION;
        };

        float4 _Color;
        sampler2D _MainTex;
        float4 _MainTex_ST;

        v2f vert(appdata v)
        {
           v2f o;
           o.vertex = UnityObjectToClipPos(v.vertex);
           o.uv = TRANSFORM_TEX(v.uv, _MainTex);
           return o;
        }

        fixed4 frag(v2f i) : SV_Target
        {
           fixed4 texColor = tex2D(_MainTex, i.uv);
           return fixed4(_Color.rgb, texColor.a);
        }
           //fixed4 frag(v2f i) : SV_Target
           //{
           //return _Color;
           //}

           //#include "CGIncludes/Spine-Skeleton-Lit-Common.cginc"
           ENDCG
              }

        Pass {
           Name "Normal"

           Tags { "LightMode" = "Vertex" "Queue" = "Transparent" "IgnoreProjector" = "true" "RenderType" = "Transparent" }

           ZWrite Off
           Cull Off
           Blend SrcAlpha OneMinusSrcAlpha

           CGPROGRAM
           #pragma shader_feature _ _STRAIGHT_ALPHA_INPUT
           #pragma shader_feature _ _DOUBLE_SIDED_LIGHTING
           #pragma vertex vert
           #pragma fragment frag
           #pragma target 2.0

           #pragma multi_compile __ POINT SPOT
           #include "CGIncludes/Spine-Skeleton-Lit-Common.cginc"
           ENDCG

        }

        Pass {
           Name "Caster"
           Tags { "LightMode" = "ShadowCaster" }
           Offset 1, 1

           Fog { Mode Off }
           ZWrite On
           ZTest LEqual
           Cull Off
           Lighting Off

           CGPROGRAM
           #pragma vertex vertShadow
           #pragma fragment fragShadow
           #pragma multi_compile_shadowcaster
           #pragma fragmentoption ARB_precision_hint_fastest

           #define SHADOW_CUTOFF _Cutoff
           #include "CGIncludes/Spine-Skeleton-Lit-Common-Shadow.cginc"

           ENDCG
        }

  }
     CustomEditor "SpineShaderWithOutlineGUI"
}

but I am getting the same results. the outline is still there.

I am sure there is some sort of noob-bug here. Can you help out?
thanks

Harald

At least you are one stop closer to your goal now, as the exposed hand is now looking better instead of being a box 😉.

Unfortunately it's impossible to judge the screenshot visually in terms of hard vs. soft pixel borders, as the jpeg compression artifacts blur everything together. It even looks as if you have added some glow effect 8). Please always prefer png screenshots to jpeg for this reason.

Which shader are you using as your normal shader, could you please also post screenshot of your Material settings? Maybe there is some alpha threshold clipping active.

It would then require this additional line:

clip(texColor.a - _Cutoff);
// which is a simpler version of ALPHA_CLIP(texColor, vertexColor) which is used in other Spine shaders

Mehran

thank you! I think that fixed it.

now I need to add another control to this so that I can enable the whole overlay effect.
here is the material

Harald

Glad to hear you've figured it out.

Mehran đã viết
now I need to add another control to this so that I can enable the whole overlay effect.
here is the material

If you need to use an additional pass for your effect (as I see in your shader with Pass { Name "overlay"..), it is most likely the best way to switch the material (or the used shader at the material) so that you don't have an unnecessary empty pass. The other (wasteful) way would be to add a keyword and have two codebranches in the fragment shader like this:

fixed4 frag(v2f i) : SV_Target
{
#if defined(_OVERLAY_ENABLED)
    // normal overlay frag code
#else
    discard;
#endif 
}